blob: 66d4180dd50c53c96b3ebbdaaaafc4aaa28cd66f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
|
# $Id: PKGBUILD 119857 2011-04-16 04:00:46Z eric $
# Maintainer: Eric Bélanger <eric@archlinux.org>
pkgname=fvwm-devel
pkgver=2.7.0
pkgrel=1
pkgdesc="A multiple large virtual desktop window manager originally derived from twm"
arch=('i686' 'x86_64')
url="http://www.fvwm.org"
license=('GPL' 'custom')
depends=('imlib' 'fribidi' 'perl' 'libstroke' 'libxpm' 'readline' 'librsvg')
makedepends=('pkg-config')
conflicts=('fvwm')
provides=("fvwm=${pkgver}")
source=(ftp://ftp.fvwm.org/pub/fvwm/version-2/fvwm-${pkgver}.tar.bz2 fvwm-devel.desktop)
md5sums=('c7dbb0c067f570e478005edb95dcccc3'
'3f5bcb246e035ff29aa5bf54487a3db4')
sha1sums=('bc8f84902b0926df171d059eff75780a25c8a97a'
'17db773870637b410ceb4f68743dbd517bc5c599')
build() {
cd "${srcdir}/fvwm-${pkgver}"
./configure --prefix=/usr --sysconfdir=/etc --libexecdir=/usr/lib --with-stroke-library
make
}
package() {
cd "${srcdir}/fvwm-${pkgver}"
make DESTDIR="${pkgdir}" install
install -d "${pkgdir}/etc/fvwm"
install -D -m644 sample.fvwmrc/* "${pkgdir}/etc/fvwm"
rm -f "${pkgdir}"/etc/fvwm/Makefile*
install -D -m644 ../fvwm-devel.desktop "${pkgdir}/usr/share/xsessions/fvwm-devel.desktop"
install -D -m644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
}
|
