blob: de873b4dfa89b1474158b122594fbba4fdbdc096 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# $Id: PKGBUILD 162652 2012-06-27 15:29:03Z bisson $
# Maintainer: Gaetan Bisson <bisson@archlinux.org>
# Contributor: Andreas Radke <andyrtr@archlinux.org>
# Contributor: damir <damir@archlinux.org>
pkgname=gcin
pkgver=2.7.6.1
pkgrel=2
pkgdesc='Input method server supporting various input methods'
url='http://hyperrate.com/dir.php?eid=67'
license=('LGPL')
arch=('i686' 'x86_64')
depends=('gtk3' 'libxtst')
makedepends=('qt' 'gtk2' 'anthy' 'libchewing')
optdepends=('qt: support for qt4 input method'
'gtk2: support for gtk2 input method'
'anthy: support for anthy input method'
'libchewing: support for chewing input method')
source=("http://www.csie.nctu.edu.tw/~cp76/gcin/download/${pkgname}-${pkgver}.tar.xz"
'qt4.patch')
sha1sums=('02319cceb5ed56d22193de0bf1f59bab9e4ab3ab'
'1c6cdcaa218615e53869bb9d67d7f9d2141e86fe')
install=install
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
patch -p1 -i ../qt4.patch
sed '/include suffixes-rule/a \
CFLAGS+='"${CFLAGS}"' \
LDFLAGS+='"${LDFLAGS}"' \
OPTFLAGS=' \
-i Makefile
./configure --prefix=/usr --use_i18n=Y
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
}
|
