blob: c9d8cb147da5e5ee8ae291c633bbd0689d25181f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
|
# $Id: PKGBUILD 157391 2012-04-28 09:26:29Z allan $
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor: Jan de Groot <jgc@archlinux.org>
pkgname=gedit
pkgver=3.4.1
pkgrel=2
pkgdesc="A text editor for GNOME"
arch=('i686' 'x86_64')
license=('GPL')
depends=('gtksourceview3' 'gsettings-desktop-schemas' 'libpeas' 'enchant' 'iso-codes' 'libsm' 'desktop-file-utils' 'python2-gobject' 'dconf')
makedepends=('yelp-tools' 'intltool')
groups=('gnome-extra')
options=('!libtool' '!emptydirs')
url="http://www.gnome.org"
install=gedit.install
source=(http://ftp.gnome.org/pub/gnome/sources/$pkgname/${pkgver%.*}/$pkgname-$pkgver.tar.xz)
sha256sums=('9b1f0164d6c6bc08e391efde7e6a2aa9290a65bda543fe3a7adc6ef73b722a64')
build() {
cd $pkgname-$pkgver
PYTHON=/usr/bin/python2 ./configure --prefix=/usr \
--sysconfdir=/etc --localstatedir=/var \
--libexecdir=/usr/lib --disable-updater --disable-schemas-compile \
--enable-python
make
}
package(){
cd $pkgname-$pkgver
make DESTDIR="$pkgdir" install
}
|
