blob: 77d8aa1022ac74947e95eb5d47d1ee1d1689034a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
|
# $Id: PKGBUILD 214068 2014-06-03 08:38:02Z jgc $
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor: Jan de Groot <jgc@archlinux.org>
pkgname=gedit
pkgver=3.12.2
pkgrel=1
pkgdesc="A text editor for GNOME"
arch=(i686 x86_64)
license=(GPL)
depends=(gtksourceview3 gsettings-desktop-schemas libpeas enchant iso-codes desktop-file-utils python-gobject dconf)
makedepends=(yelp-tools intltool zeitgeist vala)
optdepends=('zeitgeist: Zeitgeist plugin')
groups=(gnome-extra)
options=('!emptydirs')
url="http://www.gnome.org"
install=gedit.install
source=(http://ftp.gnome.org/pub/gnome/sources/$pkgname/${pkgver:0:4}/$pkgname-$pkgver.tar.xz)
sha256sums=('75460b112bed459a0f9db60e7fb0b9e6341dc8e5c20088d929597ba030d7b653')
build() {
cd $pkgname-$pkgver
./configure --prefix=/usr \
--sysconfdir=/etc --localstatedir=/var \
--libexecdir=/usr/lib --disable-updater --disable-schemas-compile \
--enable-python
make
}
package(){
cd $pkgname-$pkgver
make DESTDIR="$pkgdir" install
}
|
