blob: 5b3920e4d96c0aa2a098ce055f16bbb9df164c74 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# $Id: PKGBUILD 185106 2013-05-11 07:24:47Z bpiotrowski $
# Maintainer: Jan de Groot <jgc@archlinux.org>
# Contributor: Baptiste Daroussin <baptiste.daroussin@gmail.com>
# Contributor: Grigorios Bouzakis <grbzks[at]gmail[dot]com>
# Contributor: mightyjaym <jm.ambrosino@free.fr>
pkgname=giflib
pkgver=4.2.1
pkgrel=1
pkgdesc="A library for reading and writing gif images"
url="http://sourceforge.net/projects/giflib/"
arch=('i686' 'x86_64')
license=('MIT')
depends=('libx11')
makedepends=('xmlto' 'docbook-xml' 'docbook-xsl')
provides=("libungif=${pkgver}")
conflicts=('libungif')
replaces=('libungif')
options=('!libtool')
source=(http://downloads.sourceforge.net/sourceforge/giflib/${pkgname}-${pkgver}.tar.bz2)
md5sums=('bbd3324af24156d5d7e66ab1cee8508d')
prepare() {
cd ${pkgname}-${pkgver}
sed -i -e '/AC_PATH_XTRA/d' -e 's/AM_CONFIG_HEADER/AC_CONFIG_HEADER/' configure.ac
autoreconf -fi
}
build() {
cd ${pkgname}-${pkgver}
./configure --prefix=/usr --disable-static
make
# libungif compatibility - instructions taken from Redhat specfile
MAJOR=`echo ${pkgver} | sed 's/\([0-9]\+\)\..*/\1/'`
gcc -shared -Wl,-soname,libungif.so.${MAJOR} -Llib/.libs -lgif -o libungif.so.${pkgver}
}
package() {
cd ${pkgname}-${pkgver}
make DESTDIR="${pkgdir}" install
install -m755 libungif.so.${pkgver} "${pkgdir}/usr/lib/"
ln -sf libungif.so.${pkgver} "${pkgdir}/usr/lib/libungif.so.4"
ln -sf libungif.so.4 "${pkgdir}/usr/lib/libungif.so"
install -Dm644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
}
|
