blob: 8ec40cf551780fdfea20b173db51f2152ed401f7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
|
# $Id: PKGBUILD 127466 2011-06-15 14:36:25Z ibiru $
# Maintainer: Jan de Groot <jgc@archlinux.org>
# Contributor: Ben <ben@benmazer.net>
pkgname=gmime
pkgver=2.4.25
pkgrel=1
pkgdesc="Core mime parsing library"
arch=('i686' 'x86_64')
license=('GPL')
url="http://spruce.sourceforge.net/gmime/"
depends=('glib2' 'zlib')
makedepends=('gtk-sharp-2' 'pkgconfig')
options=('!libtool')
source=(http://ftp.gnome.org/pub/GNOME/sources/${pkgname}/${pkgver%.*}/${pkgname}-${pkgver}.tar.xz)
sha256sums=('c1044330652e7098b58e4b9c32202c5c99534da34aa260fc3b7cf8506cd56413')
build() {
# get rid of that .wapi errors in fakeroot
export MONO_SHARED_DIR="${srcdir}/weird"
mkdir -p "${MONO_SHARED_DIR}"
cd "${srcdir}/${pkgname}-${pkgver}"
./configure --prefix=/usr
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
# These are gmime alternatives for the same shareutils tools
mv "${pkgdir}/usr/bin/uuencode" "${pkgdir}/usr/bin/guuencode"
mv "${pkgdir}/usr/bin/uudecode" "${pkgdir}/usr/bin/guudecode"
}
|
