blob: ecd996b4d89a2da3a4666a8b2f202c42a6645ff5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# $Id: PKGBUILD 114760 2011-03-15 22:43:17Z andrea $
# Maintainer: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Roman Kyrylych <roman@archlinux.org>
# Contributor: Aurelien Foret <orelien@chez.com>
pkgname=gnokii
pkgver=0.6.30
pkgrel=1
pkgdesc="Tools and user space driver for use with mobile phones"
arch=('i686' 'x86_64')
url="http://www.gnokii.org/"
license=('GPL')
depends=('libusb-compat' 'libxpm' 'bluez' 'libical' 'postgresql-libs')
makedepends=('gtk2' 'libmysqlclient' 'intltool')
optdepends=('gtk2: xgnokii GUI'
'libmysqlclient: smsd mysql backend'
'postgresql-libs: smsd postgresql backend')
backup=('etc/gnokiirc')
options=('!libtool' '!makeflags')
source=(http://www.gnokii.org/download/$pkgname/$pkgname-${pkgver}.tar.bz2
'gnokii.patch')
md5sums=('c90137d403febbc16712d64f0eb196de'
'4d764727686ee34bc73489c8b1321c82')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
# FS#13249
sed -i 's|cellphone|phone|' xgnokii/xgnokii.desktop.in
patch -Np1 -i "${srcdir}/gnokii.patch"
./configure --prefix=/usr \
--sysconfdir=/etc \
--enable-security \
--disable-unix98test
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
install -Dm644 Docs/sample/gnokiirc "${pkgdir}/etc/gnokiirc"
}
|
