blob: 5f92e8071ac8336185ca004e5d62d196a16b8dc3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# $Id: PKGBUILD 213637 2014-05-27 08:41:53Z jgc $
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor: Jan de Groot <jgc@archlinux.org>
pkgname=gnome-control-center
pkgver=3.12.1
pkgrel=3
pkgdesc="The Control Center for GNOME"
license=(GPL)
arch=(i686 x86_64)
depends=(accountsservice cups-pk-helper gnome-bluetooth gnome-desktop gnome-menus
gnome-online-accounts gnome-settings-daemon gsettings-desktop-schemas gtk3
libgtop network-manager-applet sound-theme-freedesktop upower libpwquality
gnome-color-manager smbclient libmm-glib libgnomekbd grilo clutter-gtk)
makedepends=(gnome-doc-utils intltool docbook-xsl gnome-common modemmanager)
optdepends=('system-config-printer: Printer settings'
'gnome-user-share: Bluetooth and WebDAV file sharing'
'rygel: media sharing'
'vino: screen sharing'
'openssh: remote login'
'ntp: network time sync')
groups=(gnome)
url="http://www.gnome.org"
install=gnome-control-center.install
options=('!emptydirs')
source=(http://download.gnome.org/sources/$pkgname/${pkgver:0:4}/$pkgname-$pkgver.tar.xz)
sha256sums=('5297d448eff0ec58f6c0ad9fbd1b94bed0a850496df0ee65571c0622b49c1582')
build() {
cd $pkgname-$pkgver
./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
--libexecdir=/usr/lib/$pkgname --disable-static --disable-silent-rules
#https://bugzilla.gnome.org/show_bug.cgi?id=656229
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0 /g' -e 's/ if test "$export_dynamic" = yes && test -n "$export_dynamic_flag_spec"; then/ func_append compile_command " -Wl,-O1,--as-needed"\n func_append finalize_command " -Wl,-O1,--as-needed"\n\0/' libtool
make
}
package() {
cd $pkgname-$pkgver
make DESTDIR="$pkgdir" install
# Fix a warning
chown 102:0 "$pkgdir/usr/share/polkit-1/rules.d"
chmod 700 "$pkgdir/usr/share/polkit-1/rules.d"
}
|
