blob: 6f87c5ba704dbbf8ab266dddbd8d08f92515fbac (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
|
# $Id: PKGBUILD 185463 2013-05-14 10:32:30Z heftig $
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
pkgname=gnome-session
pkgver=3.8.2
pkgrel=1
pkgdesc="The GNOME Session Handler"
arch=(i686 x86_64)
license=(GPL LGPL)
depends=(systemd dconf gconf gsettings-desktop-schemas gtk3 gnome-desktop
hicolor-icon-theme json-glib libgl libsm libxtst upower)
makedepends=(intltool mesa gtk-doc xtrans)
options=('!emptydirs')
install=gnome-session.install
url="http://www.gnome.org"
groups=(gnome)
source=(http://download.gnome.org/sources/$pkgname/${pkgver::3}/$pkgname-$pkgver.tar.xz
timeout.patch)
sha256sums=('a6ed1c109005f81ec34a8aa09b2f114c07b4fba8feef47d2f23559797be88640'
'9eaf31857b41db417475c3b14adc11b10c8226ed76978cdf96dd648fa6e505fc')
build() {
cd $pkgname-$pkgver
# Increase timeout, for slow machines
patch -Np1 -i ../timeout.patch
./configure --prefix=/usr --sysconfdir=/etc \
--localstatedir=/var --libexecdir=/usr/lib/gnome-session \
--disable-schemas-compile --enable-systemd
make
}
package() {
cd $pkgname-$pkgver
make DESTDIR="$pkgdir" install
}
|
