blob: c391b081890e88e4452a5982da32b0c3b14c4d16 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
# $Id: PKGBUILD 210480 2014-04-14 20:06:46Z jgc $
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
pkgname=gnome-session
pkgver=3.12.0
pkgrel=1
pkgdesc="The GNOME Session Handler"
arch=(i686 x86_64)
license=(GPL LGPL)
depends=(systemd dconf gsettings-desktop-schemas gtk3 gnome-desktop
hicolor-icon-theme json-glib libgl libsm libxtst systemd dbus-glib)
makedepends=(intltool mesa gtk-doc xtrans)
options=('!emptydirs')
install=gnome-session.install
url="http://www.gnome.org"
groups=(gnome)
source=(http://download.gnome.org/sources/$pkgname/${pkgver%.*}/$pkgname-$pkgver.tar.xz
timeout.patch)
sha256sums=('a39306c46f153c857797f71d0cb8aad041b173d5e6acec7e47abcb3836d952d3'
'9eaf31857b41db417475c3b14adc11b10c8226ed76978cdf96dd648fa6e505fc')
prepare() {
cd $pkgname-$pkgver
# Increase timeout, for slow machines
patch -Np1 -i ../timeout.patch
}
build() {
cd $pkgname-$pkgver
./configure --prefix=/usr --sysconfdir=/etc \
--localstatedir=/var --libexecdir=/usr/lib/gnome-session \
--disable-schemas-compile --enable-systemd --disable-gconf
make
}
package() {
cd $pkgname-$pkgver
make DESTDIR="$pkgdir" install
}
|
