blob: 067f518854e213cb155a68ebe761da60617ff289 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# $Id: PKGBUILD 188077 2013-06-08 11:18:22Z bpiotrowski $
# Maintainer: Aaron Griffin <aaron@archlinux.org>
# Contributor: Mark Schneider <queueRAM@gmail.com>
pkgname=gnucash
pkgver=2.4.13
pkgrel=1
pkgdesc="A personal and small-business financial-accounting application"
arch=('i686' 'x86_64')
url="http://www.gnucash.org"
license=("GPL")
depends=('gtkhtml' 'slib' 'goffice0.8' 'libgnomeui' 'libdbi-drivers' 'aqbanking' 'desktop-file-utils')
makedepends=('intltool')
optdepends=('evince: for print preview'
'perl-finance-quote: for stock information lookups'
'perl-date-manip: for stock information lookups')
options=('!libtool' '!makeflags' '!emptydirs')
install=gnucash.install
source=(http://downloads.sourceforge.net/sourceforge/${pkgname}/${pkgname}-${pkgver}.tar.bz2)
sha1sums=('cd28d4e7d84d71ade56173734d634ccadc59ed81')
prepare() {
cd "${srcdir}/${pkgname}-${pkgver}"
sed -i 's|guile-config|guile-config1.8|g' configure
}
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
export GUILE=/usr/bin/guile1.8
./configure --prefix=/usr --mandir=/usr/share/man --sysconfdir=/etc \
--libexecdir=/usr/lib --disable-schemas-install --enable-ofx --enable-aqbanking
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make GCONF_DISABLE_MAKEFILE_SCHEMA_INSTALL=1 DESTDIR="${pkgdir}" install
cd src/doc/design
make DESTDIR="${pkgdir}" install-info
install -dm755 "${pkgdir}/usr/share/gconf/schemas"
gconf-merge-schema "${pkgdir}/usr/share/gconf/schemas/${pkgname}.schemas" --domain gnucash "${pkgdir}"/etc/gconf/schemas/*.schemas
rm -f "${pkgdir}"/etc/gconf/schemas/*.schemas
}
|
