blob: 4fa63dfbe14fc7047039a1e62915b3c4268ec87a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# $Id: PKGBUILD 213531 2014-05-24 01:23:48Z dreisner $
# Maintainer: Dave Reisner <dreisner@archlinux.org>
# Contributor: Alexander Rødseth <rodseth@gmail.com>
# Contributor: Thomas Jost <schnouki@schnouki.net>
# Contributor: JaDa <jada@archlinux.us>
# Contributor: Joaquim Pedro <osmano807@gmail.com>
# Contributor: Jan Rüegg <rggjan@gmail.com>
pkgname=gperftools
pkgver=2.2
pkgrel=1
pkgdesc="Fast, multi-threaded malloc() and nifty performance analysis tools"
arch=('i686' 'x86_64')
url="http://code.google.com/p/gperftools/"
license=('BSD')
depends=('perl')
provides=('libtcmalloc.so'
'libprofiler.so'
'libtcmalloc_debug.so'
'libtcmalloc_and_profiler.so'
'libtcmalloc_minimal.so'
'libtcmalloc_minimal_debug.so')
makedepends=('git')
optdepends=('graphviz: pprof graph generation'
'gv: pprof postscript generation')
source=("git+https://code.google.com/p/gperftools#tag=gperftools-$pkgver")
md5sums=('SKIP')
prepare() {
cd "$pkgname"
./autogen.sh
}
build() {
cd "$pkgname"
./configure --prefix=/usr --enable-frame-pointers
make
}
package() {
cd "$pkgname"
make DESTDIR="$pkgdir" install
install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}
# vim:set ts=2 sw=2 et:
|
