blob: 82f855ed98e10acdc33d2981e3a796c5a64b24f9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# $Id: PKGBUILD 103133 2010-12-15 19:32:43Z ronald $
# Maintainer: Ronald van Haren <ronald.archlinux.org>
# Contributor: Jaroslav Lichtblau <dragonlord@aur.archlinux.org>
# Contributor: Anton Leontiev <bunder@t-25.ru>
pkgname=graphicsmagick
pkgver=1.3.12
pkgrel=1
pkgdesc="Image processing system"
arch=('i686' 'x86_64')
url="http://www.graphicsmagick.org/"
license=('MIT')
makedepends=('perl')
depends=('bzip2' 'freetype2' 'ghostscript' 'jasper' 'lcms' 'libsm'
'libtiff' 'libwmf' 'libxml2' 'libtool')
options=('!libtool')
source=(http://downloads.sourceforge.net/sourceforge/${pkgname}/${pkgname}-history/1.3/GraphicsMagick-${pkgver}.tar.gz)
md5sums=('2cf6e2eea0d7af3019c9a89b81aad624')
build() {
cd "${srcdir}/GraphicsMagick-$pkgver"
./configure --prefix=/usr --with-perl --enable-shared --with-gs-font-dir=/usr/share/fonts/Type1
make
}
package() {
cd "${srcdir}/GraphicsMagick-$pkgver"
make DESTDIR="${pkgdir}" install
# Install MIT license
install -Dm644 "Copyright.txt" "${pkgdir}/usr/share/licenses/$pkgname/Copyright.txt"
# Install perl bindings
# The patching was introduced in order to build perl module without installing package itself and
# not to introduce unnecessary path into LD_RUN_PATH
cd PerlMagick
sed -i -e "s:'LDDLFLAGS' => \"\(.*\)\":'LDDLFLAGS' => \"-L${pkgdir}/usr/lib \1\":" Makefile.PL
perl Makefile.PL INSTALLDIRS=vendor PREFIX=/usr DESTDIR="${pkgdir}"
sed -i -e "s/LDLOADLIBS =/LDLOADLIBS = -lGraphicsMagick/" Makefile
make
make install
# Remove perllocal.pod and .packlist
rm -rf "${pkgdir}/usr/lib/perl5/core_perl"
rm "${pkgdir}/usr/lib/perl5/vendor_perl/auto/Graphics/Magick/.packlist"
}
|
