blob: 884b8cec125c28838f0f2690441fd648c087a46d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# $Id: PKGBUILD 203404 2014-01-10 04:16:47Z bisson $
# Maintainer: Gaetan Bisson <bisson@archlinux.org>
# Contributor: kevin <kevin@archlinux.org>
# Contributor: John Proctor <jproctor@prium.net>
pkgname=graphviz
pkgver=2.34.0
pkgrel=3
pkgdesc='Graph visualization software'
url='http://www.graphviz.org/'
license=('CPL')
arch=('i686' 'x86_64')
depends=('libltdl' 'gd' 'librsvg' 'libxaw' 'ghostscript' 'pango' 'gts')
makedepends=('swig' 'mono' 'guile' 'lua51' 'ocaml' 'perl' 'php' 'python2' 'r' 'tk' 'qt4')
optdepends=('mono: sharp bindings'
'guile: guile bindings'
'lua51: lua bindings'
'ocaml: ocaml bindings'
'perl: perl bindings'
'php: php bindings'
'python2: python bindings'
'r: r bindings'
'tcl: tcl bindings'
'qt4: gvedit')
source=("${url}/pub/${pkgname}/stable/SOURCES/${pkgname}-${pkgver}.tar.gz"
'yyerror0.patch'
'yyerror1.patch'
'dotty.patch')
sha1sums=('5a0c00bebe7f4c7a04523db21f40966dc9f0d441'
'7a6fe4f532974d9ca173b1aba9927bdeb5f80be9'
'6d76a230ee6c11bcd610ebe56f98e96ecef6217d'
'31bc9f505c8b6470289a0d6ec31c237765cba239')
install=install
prepare() {
cd "${srcdir}/${pkgname}-${pkgver}"
patch -p1 -i ../yyerror0.patch
patch -p1 -i ../yyerror1.patch
patch -p1 -i ../dotty.patch
sed \
-e '/LIBPOSTFIX="64"/d' \
-i configure
}
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
export PYTHON=python2
export LUA=lua5.1
./configure --prefix=/usr
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
}
|
