blob: 59f3d12a0615c01f57af751320ef5c27f4ea53b4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# $Id: PKGBUILD 203416 2014-01-10 14:44:32Z heftig $
# Maintainer: Jan de Groot <jgc@archlinux.org>
pkgname=gst-plugins-good
pkgver=1.2.2
pkgrel=2
pkgdesc="GStreamer Multimedia Framework Good Plugins"
arch=('i686' 'x86_64')
license=('LGPL')
url="http://gstreamer.freedesktop.org/"
depends=('libpulse' 'jack' 'libsoup' 'gst-plugins-base-libs' 'wavpack' 'aalib' 'taglib' 'libdv' 'libshout' 'libvpx' 'gdk-pixbuf2' 'libcaca' 'libavc1394' 'libiec61883' 'libxdamage' 'v4l-utils' 'cairo')
makedepends=('gstreamer' 'speex' 'flac' 'libraw1394' 'python' 'gtk-doc')
options=(!emptydirs)
source=(${url}/src/$pkgname/$pkgname-$pkgver.tar.xz)
sha256sums=('6c090f00e8e4588f12807bd9fbb06a03b84a512c93e84d928123ee4a42228a81')
build() {
cd $pkgname-$pkgver
./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
--disable-static --enable-experimental --enable-gtk-doc \
--with-package-name="GStreamer Good Plugins (Arch Linux)" \
--with-package-origin="http://www.archlinux.org/"
# https://bugzilla.gnome.org/show_bug.cgi?id=655517
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
make
}
# Disabled for now: souphttpsrc times out, and takes a damn long time to do so
#check() {
# cd $pkgname-$pkgver
# make check
#}
package() {
cd $pkgname-$pkgver
make DESTDIR="${pkgdir}" install
}
|
