blob: b19368690b709e334c65b1e21006362cfb0abd7c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
|
# $Id: PKGBUILD 178130 2013-02-16 22:48:48Z ioni $
# Maintainer: Jan de Groot <jgc@archlinux.org>
pkgname=gst-plugins-ugly
pkgver=1.0.5
pkgrel=2
pkgdesc="GStreamer Multimedia Framework Ugly Plugins"
arch=('i686' 'x86_64')
license=('LGPL')
url="http://gstreamer.freedesktop.org/"
depends=('gst-plugins-base-libs' 'libdvdread' 'lame' 'libmpeg2' 'a52dec' 'libmad' 'libsidplay' 'libcdio' 'x264' 'opencore-amr')
options=(!libtool !emptydirs)
source=(${url}/src/$pkgname/$pkgname-$pkgver.tar.xz)
sha256sums=('a62a182ea96d9b2783b493b46d531914db9d2ebb9e537e9c84668fe752791331')
build() {
cd $pkgname-$pkgver
sed -i '/AC_PATH_XTRA/d' configure.ac
aclocal -I m4 -I common/m4
autoconf
automake --add-missing
./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
--disable-static --enable-experimental \
--with-package-name="GStreamer Ugly Plugins (Archlinux)" \
--with-package-origin="http://www.archlinux.org/"
make
}
check() {
cd $pkgname-$pkgver
make check
}
package() {
cd $pkgname-$pkgver
make DESTDIR="${pkgdir}" install
}
|
