blob: ad3fe3b5727d3c6663bb0b5da936d0da2087f227 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# $Id: PKGBUILD 117108 2011-03-28 19:26:10Z ibiru $
# Maintainer: Jan de Groot <jgc@archlinux.org>
pkgbase=gstreamer0.10-ugly
pkgname=('gstreamer0.10-ugly' 'gstreamer0.10-ugly-plugins')
pkgver=0.10.17
pkgrel=2
arch=('i686' 'x86_64')
license=('LGPL')
makedepends=('pkgconfig' 'gstreamer0.10-base>=0.10.32' 'libdvdread' 'lame' 'libmpeg2' 'a52dec' 'libid3tag' 'libmad' 'libsidplay' 'libcdio' 'x264' 'opencore-amr')
url="http://gstreamer.freedesktop.org/"
options=(!libtool)
source=(${url}/src/gst-plugins-ugly/gst-plugins-ugly-${pkgver}.tar.bz2)
md5sums=('504ed6508c3a8f035a2002ed69d68506')
build() {
cd "${srcdir}/gst-plugins-ugly-${pkgver}"
./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
--disable-static --enable-experimental \
--with-package-name="GStreamer Ugly Plugins (Archlinux)" \
--with-package-origin="http://www.archlinux.org/"
make
sed -e 's/gst-libs gst ext/gst-libs gst/' -i Makefile
}
package_gstreamer0.10-ugly() {
pkgdesc="GStreamer Multimedia Framework Ugly plugin libraries"
depends=('gstreamer0.10-base>=0.10.32')
cd "${srcdir}/gst-plugins-ugly-${pkgver}"
make DESTDIR="${pkgdir}" install
}
package_gstreamer0.10-ugly-plugins() {
pkgdesc="GStreamer Multimedia Framework Ugly Plugins (gst-plugins-ugly)"
depends=("gstreamer0.10-ugly=${pkgver}" 'libdvdread' 'lame' 'libmpeg2' 'a52dec' 'libid3tag' 'libmad' 'libsidplay' 'libcdio' 'x264' 'opencore-amr')
groups=('gstreamer0.10-plugins')
replaces=('gstreamer0.10-dvdread' 'gstreamer0.10-mpeg2dec' 'gstreamer0.10-mad' 'gstreamer0.10-lame' 'gstreamer0.10-sidplay' 'gstreamer0.10-a52dec')
conflicts=('gstreamer0.10-dvdread' 'gstreamer0.10-mpeg2dec' 'gstreamer0.10-mad' 'gstreamer0.10-lame' 'gstreamer0.10-sidplay' 'gstreamer0.10-a52dec')
cd "${srcdir}/gst-plugins-ugly-${pkgver}"
make -C ext DESTDIR="${pkgdir}" install
}
|
