blob: 89219d5bc52cf6e96c3f94ccc85c6373708ecb0b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
|
# $Id: PKGBUILD 124024 2011-05-16 07:21:10Z jgc $
# Maintainer: Jan de Groot <jgc@archlinux.org>
pkgname=gstreamer0.10
pkgver=0.10.34
pkgrel=1
pkgdesc="GStreamer Multimedia Framework"
arch=('i686' 'x86_64')
license=('LGPL')
url="http://gstreamer.freedesktop.org/"
depends=('libxml2' 'glib2')
optdepends=('sh: feedback script')
makedepends=('intltool' 'pkgconfig' 'gtk-doc' 'gobject-introspection')
options=('!libtool')
source=(${url}/src/gstreamer/gstreamer-${pkgver}.tar.bz2)
sha256sums=('85348f70dc4b70ad1beb05c9a59a64175c5058f4ee5273f89230a3c1d11b26a3')
build() {
cd "${srcdir}/gstreamer-${pkgver}"
./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var --libexecdir=/usr/lib \
--with-package-name="GStreamer (Archlinux)" \
--with-package-origin="http://www.archlinux.org/" \
--enable-gtk-doc --disable-static
make
}
package() {
cd "${srcdir}/gstreamer-${pkgver}"
make DESTDIR="${pkgdir}" install
#Remove unversioned gst-* binaries to get rid of conflicts
cd "${pkgdir}/usr/bin"
for bins in `ls *-0.10`; do
rm -f ${bins/-0.10/}
done
}
|
