blob: ba1b7f98ac6807e1fb68b1e2130fe4a348e98a0c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
|
# $Id: PKGBUILD 216302 2014-07-03 01:49:15Z eric $
# Maintainer: Eric Bélanger <eric@archlinux.org>
pkgname=gv
pkgver=3.7.4
pkgrel=2
pkgdesc="A program to view PostScript and PDF documents"
arch=('i686' 'x86_64')
url="http://www.gnu.org/software/gv/"
license=('GPL3')
depends=('xaw3d' 'ghostscript' 'desktop-file-utils')
options=('emptydirs')
install=gv.install
source=(http://ftp.gnu.org/gnu/gv/${pkgname}-${pkgver}.tar.gz{,.sig} gv.desktop)
sha1sums=('d5bc11a37136dff69248f943a632544a4036b63f'
'7d8b7edd60617b189ba39ca982252b0d59c0755d'
'b40ccad8a8d837791598075f543edce9aa1f4352')
prepare() {
cd ${pkgname}-${pkgver}
sed -i -e "s:-dGraphicsAlphaBits=2:\0 -dAlignToPixels=0:" src/Makefile.{am,in}
}
build() {
cd ${pkgname}-${pkgver}
./configure --prefix=/usr
make
}
package() {
cd ${pkgname}-${pkgver}
make DESTDIR="${pkgdir}" install
install -D -m644 ../gv.desktop "${pkgdir}/usr/share/applications/gv.desktop"
install -D -m644 src/gv_icon.xbm "${pkgdir}/usr/share/pixmaps/gv.xbm"
}
|
