blob: caa32f0157e9fbf6a82c18d7aeeb5e1b20a617cb (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# $Id: PKGBUILD 198735 2013-11-02 15:15:10Z heftig $
# Maintainer: Jan de Groot <jgc@archlinux.org>
pkgbase=(harfbuzz)
pkgname=(harfbuzz harfbuzz-icu)
pkgver=0.9.23
pkgrel=1
pkgdesc="OpenType text shaping engine"
arch=(i686 x86_64)
url="http://www.freedesktop.org/wiki/Software/HarfBuzz"
license=(MIT)
makedepends=(glib2 freetype2 graphite cairo icu gobject-introspection)
source=(http://www.freedesktop.org/software/harfbuzz/release/${pkgbase}-${pkgver}.tar.bz2)
sha256sums=('171ab7f58e7243082a4582f4d1f21b3f44462931ea92a6909d303ad3614794c7')
build() {
cd $pkgbase-$pkgver
./configure --prefix=/usr \
--with-glib --with-freetype --with-cairo --with-icu --with-graphite2 \
--with-gobject
make
}
package_harfbuzz() {
depends=(glib2 freetype2 graphite)
optdepends=('cairo: hb-view program')
cd $pkgbase-$pkgver
make DESTDIR="$pkgdir" install
install -Dm644 COPYING "$pkgdir/usr/share/licenses/harfbuzz/COPYING"
# Split harfbuzz-icu
mkdir -p ../hb-icu/usr/{include/harfbuzz,lib/pkgconfig}; cd ../hb-icu
mv "$pkgdir"/usr/lib/libharfbuzz-icu* ./usr/lib
mv "$pkgdir"/usr/lib/pkgconfig/harfbuzz-icu.pc ./usr/lib/pkgconfig
mv "$pkgdir"/usr/include/harfbuzz/hb-icu.h ./usr/include/harfbuzz
}
package_harfbuzz-icu(){
pkgdesc="$pkgdesc (ICU integration)"
depends=(harfbuzz icu)
mv hb-icu/* "$pkgdir"
install -Dm644 $pkgbase-$pkgver/COPYING "$pkgdir/usr/share/licenses/harfbuzz-icu/COPYING"
}
|
