blob: 509980f308667b10b3a083404e070be8a9c78935 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# $Id: PKGBUILD 173197 2012-12-12 17:29:21Z heftig $
# Maintainer: Angel Velasquez <angvp@archlinux.org>
# Contributor: Eric Belanger <eric@archlinux.org>
# Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
pkgname=htop
pkgver=1.0.2
pkgrel=2
pkgdesc="Interactive process viewer"
arch=('i686' 'x86_64')
url="http://htop.sourceforge.net/"
license=('GPL')
depends=('ncurses')
makedepends=('python2')
optdepends=('lsof: show files opened by a process'
'strace: attach to a running process')
options=('!emptydirs')
source=("http://downloads.sourceforge.net/$pkgname/$pkgname-$pkgver.tar.gz"
tree-crash.patch)
md5sums=('0d01cca8df3349c74569cefebbd9919e'
'48eba3c0303bfd19d761b859bc69d713')
build() {
cd "$pkgname-$pkgver"
sed -i 's|ncursesw/curses.h|curses.h|' RichString.[ch] configure
sed -i 's|python|python2|' scripts/MakeHeader.py
# Boost field buffer size - crashes when trying to draw very deep UTF-8 trees
# Test by nesting 30 shells
patch -N -i ../tree-crash.patch
./configure \
--prefix=/usr \
--enable-unicode \
--enable-openvz \
--enable-vserver \
--enable-cgroup
make
}
package() {
make -C "$pkgname-$pkgver" DESTDIR="$pkgdir" install
}
|
