blob: 96700f3594a71fab343453c7902c2cf07b0b6580 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# $Id: PKGBUILD 215334 2014-06-21 16:09:10Z dreisner $
# Maintainer: Angel Velasquez <angvp@archlinux.org>
# Contributor: Eric Belanger <eric@archlinux.org>
# Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
pkgname=htop
pkgver=1.0.3
pkgrel=2
pkgdesc="Interactive process viewer"
arch=('i686' 'x86_64')
url="http://htop.sourceforge.net/"
license=('GPL')
depends=('ncurses')
makedepends=('python2')
optdepends=('lsof: show files opened by a process'
'strace: attach to a running process')
options=('!emptydirs')
source=("http://hisham.hm/$pkgname/releases/$pkgver/$pkgname-$pkgver.tar.gz")
md5sums=('e768b9b55c033d9c1dffda72db3a6ac7')
prepare() {
cd "$pkgname-$pkgver"
sed -i 's|ncursesw/curses.h|curses.h|' RichString.[ch] configure
sed -i 's|python|python2|' scripts/MakeHeader.py
}
build() {
cd "$pkgname-$pkgver"
./configure \
--prefix=/usr \
--enable-unicode \
--enable-openvz \
--enable-vserver \
--enable-cgroup \
--enable-oom
make
}
package() {
make -C "$pkgname-$pkgver" DESTDIR="$pkgdir" install
}
|
