blob: bdb9624d61259f0758d335918214262593ecc743 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# $Id: PKGBUILD 204310 2014-01-17 07:31:32Z fyan $
# Maintainer: Felix Yan <felixonmars@gmail.com>
pkgbase=ibus
pkgname=(ibus libibus)
pkgver=1.5.5
pkgrel=1
pkgdesc="Next Generation Input Bus for Linux"
arch=('i686' 'x86_64')
url="http://ibus.googlecode.com"
license=('LGPL')
depends=('dconf' 'gtk2' 'gtk3' 'hicolor-icon-theme' 'libnotify' 'pygtk' 'python2-dbus' 'python2-gobject' 'iso-codes')
makedepends=('gobject-introspection' 'vala' 'gconf' 'intltool')
options=('!emptydirs')
source=(http://ibus.googlecode.com/files/${pkgbase}-${pkgver}.tar.gz)
build() {
cd ${pkgbase}-${pkgver}
export PYTHON=python2
./configure \
--prefix=/usr \
--libexecdir=/usr/lib/ibus \
--sysconfdir=/etc \
--disable-gconf \
--enable-dconf \
--disable-memconf \
--enable-ui \
--enable-python-library
make
}
package_ibus() {
depends+=("libibus=$pkgver")
install=ibus.install
cd ${pkgbase}-${pkgver}
make DESTDIR="${pkgdir}" install
make -C src DESTDIR="${pkgdir}" uninstall
make -C bindings DESTDIR="${pkgdir}" uninstall
make DESTDIR="${pkgdir}" uninstall-pkgconfigDATA
}
package_libibus() {
pkgdesc="IBus support library"
depends=('glib2')
cd ${pkgbase}-${pkgver}
make -C src DESTDIR="${pkgdir}" install
make -C bindings DESTDIR="${pkgdir}" install
make DESTDIR="${pkgdir}" install-pkgconfigDATA
}
sha512sums=('8249d6ee4918b0e0fe030af736eed2260e1376b2fdaf0d819f289e0bd880a5e3874f1fb3d097fc74b9f359822ce16f4dae52a263aa28c2e2ce7bdf671cb2fea9')
|