blob: b715c804b2e272a9041d512a5ca92d54eeeac5e6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# $Id: PKGBUILD 184396 2013-05-06 19:38:01Z foutrelis $
# Maintainer: Gaetan Bisson <bisson@archlinux.org>
# Contributor: Tobias Kieslich <tobias@justdreams.de>
# Contributor: tobias <tobias@archlinux.org>
pkgname=inkscape
pkgver=0.48.4
pkgrel=7
pkgdesc='Vector graphics editor using the SVG file format'
url='http://inkscape.sourceforge.net/'
license=('GPL' 'LGPL')
arch=('i686' 'x86_64')
makedepends=('boost' 'intltool')
depends=('gc' 'gsl' 'gtkmm' 'gtkspell' 'imagemagick' 'libxslt' 'poppler-glib>=0.22.3' 'popt'
'python2' 'desktop-file-utils' 'hicolor-icon-theme')
optdepends=('pstoedit: latex formulas'
'texlive-core: latex formulas'
'python2-numpy: some extensions'
'python2-lxml: some extensions and filters'
'pyxml: some extensions'
'uniconvertor: reading/writing to some proprietary formats')
options=('!libtool')
source=("http://downloads.sourceforge.net/project/${pkgname}/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.bz2"
'spuriouscomma.patch')
sha1sums=('5f26f6ad191d1e7c2a9fb69a438722beb172224c'
'7d1d5a6d1d2b0926721a994d5889c52890fc57c1')
install=install
prepare() {
cd "${srcdir}/${pkgname}-${pkgver}"
patch -p0 -i ../spuriouscomma.patch
sed -i 's|/usr/bin/python\>|/usr/bin/python2|g' cxxtest/*.py
sed -i 's|/usr/bin/env python\>|/usr/bin/env python2|g' share/*/{test/,}*.py
sed -i 's|"python" },|"python2" },|g' src/extension/implementation/script.cpp
sed -i 's|python -c|python2 -c|g' configure share/extensions/uniconv*.py
sed -i 's|"python"|"python2"|g' src/main.cpp
}
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
./configure \
--prefix=/usr \
--with-python \
--with-perl \
--enable-lcms \
--enable-poppler-cairo \
--disable-dependency-tracking
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
}
|
