blob: e0af1419f0269813a899070017eadbfd985843c6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# $Id: PKGBUILD 210507 2014-04-14 20:07:09Z jgc $
# Maintainer: Ionut Biru <ibiru@archlinux.org>
pkgname=js
pkgver=24.2.0
pkgrel=1
pkgdesc="JavaScript interpreter and libraries"
arch=(i686 x86_64)
url="https://developer.mozilla.org/En/SpiderMonkey/17"
license=(MPL)
depends=(nspr gcc-libs readline zlib)
makedepends=(python2 zip libffi)
options=(!staticlibs)
source=(http://ftp.mozilla.org/pub/mozilla.org/js/mozjs-$pkgver.tar.bz2)
md5sums=('5db79c10e049a2dc117a6e6a3bc78a8e')
prepare() {
rm -rf mozjs-$pkgver/js/src/editline
rm -rf mozjs-$pkgver/js/src/ctypes/libffi
}
build() {
unset CPPFLAGS
cd mozjs-$pkgver/js/src
./configure --prefix=/usr --with-system-nspr --enable-system-ffi \
--enable-readline --enable-threadsafe
make
}
check() {
cd mozjs-$pkgver/js/src
make check
}
package() {
cd mozjs-$pkgver/js/src
make DESTDIR="$pkgdir" install
find "$pkgdir"/usr/{lib/pkgconfig,include} -type f -exec chmod -x {} +
}
# vim:set ts=2 sw=2 et:
|
