blob: 894a0220cf9f6be9bd873402212b24a5960422b7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# $Id: PKGBUILD 213069 2014-05-18 19:00:08Z andrea $
# Maintainer: Andrea Scarpino <andrea@archlinux.org>
pkgbase=kactivities-frameworks
pkgname=('kactivities-frameworks' 'libkactivities-frameworks')
pkgver=4.99.0.c67df41
pkgrel=2
arch=('i686' 'x86_64')
url='https://projects.kde.org/projects/kde/kdelibs/kactivities'
license=('LGPL')
makedepends=('qt5-declarative' 'kservice' 'extra-cmake-modules' 'boost' 'git')
groups=('kf5')
#source=("http://download.kde.org/unstable/frameworks/${pkgver}/kactivities-${pkgver}.tar.xz")
source=('git://anongit.kde.org/kactivities.git#commit=c67df4161a9b2ba4b9c34be31ddb95b15fa42c2a')
md5sums=('SKIP')
prepare() {
mkdir -p build
}
build() {
cd build
cmake ../kactivities \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr \
-DLIB_INSTALL_DIR=lib \
-DQT_PLUGIN_INSTALL_DIR=lib/qt/plugins \
-DQML_INSTALL_DIR=lib/qt/qml \
-DECM_MKSPECS_INSTALL_DIR=/usr/share/qt/mkspecs/modules \
-DBUILD_TESTING=OFF
make
}
package_kactivities-frameworks() {
pkgdesc="The KActivity Manager Daemon"
depends=('kwindowsystem' 'libkactivities-frameworks')
provides=('kactivities')
conflicts=('kactivities')
cd build
install -Dm755 src/service/kactivitymanagerd \
"${pkgdir}"/usr/bin/kactivitymanagerd
}
package_libkactivities-frameworks() {
pkgdesc="Core components for the KDE's Activities"
depends=('kconfig' 'qt5-declarative' 'ki18n' 'kcoreaddons' 'kdbusaddons')
cd build
make DESTDIR="${pkgdir}" install
# Fix conflicts
rm "${pkgdir}"/usr/bin/kactivitymanagerd
rmdir "${pkgdir}"/usr/bin
}
|