blob: 7a0acda54c77477f9e4bf7f350feacafbf7f21f7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# $Id: PKGBUILD 144663 2011-12-08 09:19:28Z andrea $
# Maintainer: Andrea Scarpino <andrea@archlinux.org>
pkgbase=kdebindings-kross
pkgname=('kdebindings-kross-python'
# 'kdebindings-kross-ruby'
'kdebindings-kross-java')
pkgver=4.7.4
pkgrel=1
url="http://kde.org/"
arch=('i686' 'x86_64')
license=('GPL' 'LGPL' 'FDL')
groups=('kdebindings')
makedepends=('kdelibs' 'cmake' 'automoc4' 'python2' 'openjdk6')
source=("http://download.kde.org/stable/${pkgver}/src/kross-interpreters-${pkgver}.tar.bz2")
sha1sums=('416e9f25ff2050d9c5518254a7cc7d4cad22b648')
build() {
cd "${srcdir}"
mkdir build
cd build
cmake ../kross-interpreters-${pkgver} \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr \
-DBUILD_ruby=OFF \
-DPYTHON_EXECUTABLE=/usr/bin/python2
make
}
package_kdebindings-kross-python() {
pkgdesc="Python2 language interpreters to enable in-process scripting with Kross"
depends=('kdelibs' 'python2')
cd "${srcdir}"/build/python
make DESTDIR="${pkgdir}" install
}
package_kdebindings-kross-java() {
pkgdesc="Java language interpreters to enable in-process scripting with Kross"
depends=('kdelibs' 'openjdk6')
cd "${srcdir}"/build/java
make DESTDIR="${pkgdir}" install
}
package_kdebindings-kross-ruby() {
pkgdesc="Ruby language interpreters to enable in-process scripting with Kross"
depends=('kdelibs' 'ruby')
cd "${srcdir}"/build/ruby
make DESTDIR="${pkgdir}" install
}
|
