blob: 012021044b727a6159ad91d9e3902b71fa259eca (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
|
# $Id: PKGBUILD 189625 2013-07-03 17:04:16Z andrea $
# Maintainer: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Pierre Schmitz <pierre@archlinux.de>
pkgbase=kdewebdev
pkgname=('kdewebdev-kfilereplace'
'kdewebdev-kimagemapeditor'
'kdewebdev-klinkstatus'
'kdewebdev-kommander')
pkgver=4.10.5
pkgrel=1
arch=('i686' 'x86_64')
url='http://www.kde.org'
license=('GPL' 'LGPL' 'FDL')
groups=('kde' 'kdewebdev')
makedepends=('cmake' 'automoc4' 'ruby' 'tidyhtml' 'kdepimlibs' 'boost')
source=("http://download.kde.org/stable/${pkgver}/src/${pkgbase}-${pkgver}.tar.xz")
sha1sums=('6d81be773a08fe41cbd34ac178107e3ba3a96181')
build() {
cd $srcdir
mkdir build
cd build
cmake ../${pkgbase}-${pkgver} \
-DCMAKE_BUILD_TYPE=Release \
-DKDE4_BUILD_TESTS=OFF \
-DCMAKE_SKIP_RPATH=ON \
-DCMAKE_INSTALL_PREFIX=/usr
make
}
package_kdewebdev-kfilereplace() {
pkgdesc='Search & Replace Tool'
depends=('kdebase-runtime')
url="http://kde.org/applications/utilities/kfilereplace/"
install='kdewebdev.install'
cd $srcdir/build/kfilereplace
make DESTDIR=$pkgdir install
cd $srcdir/build/doc/kfilereplace
make DESTDIR=$pkgdir install
}
package_kdewebdev-kimagemapeditor() {
pkgdesc='HTML Image Map Editor'
depends=('kdebase-runtime')
url="http://www.kde.org/applications/development/kimagemapeditor/"
install='kdewebdev-kimagemapeditor.install'
cd $srcdir/build/kimagemapeditor
make DESTDIR=$pkgdir install
cd $srcdir/build/doc/kimagemapeditor
make DESTDIR=$pkgdir install
}
package_kdewebdev-klinkstatus() {
pkgdesc='Link Checker'
depends=('kdebase-runtime' 'kdepimlibs' 'tidyhtml')
url="http://www.kde.org/applications/development/klinkstatus/"
install='kdewebdev.install'
cd $srcdir/build/klinkstatus
make DESTDIR=$pkgdir install
cd $srcdir/build/doc/klinkstatus
make DESTDIR=$pkgdir install
}
package_kdewebdev-kommander() {
pkgdesc='Executor for Kommander dialogs'
depends=('kdebase-runtime')
url="http://www.kde.org/applications/development/kommander/"
cd $srcdir/build/kommander
make DESTDIR=$pkgdir install
}
|
