blob: 6737913e2f97704578a1370813fddecfa4dc2b47 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# $Id: PKGBUILD 110193 2011-02-17 14:28:04Z jgc $
# Maintainer: Jan de Groot <jgc@archlinux.org>
pkgname=libdrm
pkgver=2.4.23
pkgrel=2
pkgdesc="Userspace interface to kernel DRM services"
arch=(i686 x86_64)
license=('custom')
depends=('glibc')
options=('!libtool')
url="http://dri.freedesktop.org/"
source=(http://dri.freedesktop.org/${pkgname}/${pkgname}-${pkgver}.tar.bz2
no-pthread-stubs.patch
intel-git-fixes.patch
COPYING)
sha1sums=('9d651d1e394654c02343e3d95c0f8a442a91ac75'
'af2d9871565ea4cf524873f897691a18b2bba944'
'40d5a749f05dc097c91c087fe1f8b970613e9098'
'ba3dcd636997ee0d30df14b03dae05c24ae5d094')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
patch -Np1 -i "${srcdir}/no-pthread-stubs.patch"
patch -Np1 -i "${srcdir}/intel-git-fixes.patch"
libtoolize --force
autoreconf --force --install
./configure --prefix=/usr \
--enable-udev \
--enable-intel \
--enable-radeon \
--enable-vmwgfx-experimental-api \
--enable-nouveau-experimental-api
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
install -m755 -d "${pkgdir}/usr/share/licenses/${pkgname}"
install -m644 "${srcdir}/COPYING" "${pkgdir}/usr/share/licenses/${pkgname}/"
}
|
