blob: 105a060ad071d8709abbbe881ef7e979664376e2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
# $Id: PKGBUILD 198755 2013-11-03 09:14:05Z andrea $
# Maintainer: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Tobias Powalowski <tpowa@archlinux.org>
pkgname=libindi
pkgver=0.9.6
pkgrel=5
pkgdesc="A distributed control protocol designed to operate astronomical instrumentation"
url="http://www.indilib.org/index.php?title=Main_Page"
license=('GPL2')
arch=('i686' 'x86_64')
depends=('libnova' 'cfitsio' 'boost-libs' 'libusb-compat')
makedepends=('cmake' 'boost')
options=('staticlibs') # libindiclient builds as static only
source=("http://downloads.sourceforge.net/indi/${pkgname}_${pkgver}.tar.gz")
md5sums=('c1456544a36f543e2884f88913cf3eb0')
prepare() {
mkdir build
}
build() {
cd build
cmake ../${pkgname}-${pkgver} \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr
make
}
package() {
cd build
make DESTDIR="${pkgdir}" install
install -d "${pkgdir}"/usr/lib/udev/rules.d
mv "${pkgdir}"/etc/udev/rules.d/99-gpusb.rules \
"${pkgdir}"/usr/lib/udev/rules.d/
rmdir "${pkgdir}"/etc/udev/rules.d "${pkgdir}"/etc/udev "${pkgdir}"/etc
}
|
