blob: 0a17f3716e42f716494098fa3e9a218ee4e53228 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# $Id: PKGBUILD 215167 2014-06-14 19:17:19Z andyrtr $
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor: Alexander Rødseth <rodseth@gmail.com>
# Contributor: Jon Nordby <jononor@gmail.com>
pkgname=libwebp
pkgver=0.4.0
pkgrel=2
pkgdesc="WebP library and conversion tools"
arch=(x86_64 i686)
url="https://developers.google.com/speed/webp/"
license=(BSD)
depends=(libpng libjpeg libtiff giflib)
makedepends=(freeglut mesa glu)
optdepends=('freeglut: vwebp viewer')
source=("http://webp.googlecode.com/files/$pkgname-$pkgver.tar.gz"
"libwebp-0.4.0-giflib-5.1.0.patch")
sha256sums=('31913577e96386556855b41d210736449445fe96cfbe9289014e9b8afa944d69'
'466fb04887b7fba1be95bb409bd01c23c2855dc2b9471cf5cd6de1822e55ed86')
prepare() {
cd "$srcdir/$pkgname-$pkgver"
patch -p1 -i "$srcdir"/libwebp-0.4.0-giflib-5.1.0.patch
}
build() {
cd "$srcdir/$pkgname-$pkgver"
./configure --prefix=/usr \
--enable-swap-16bit-csp \
--enable-experimental \
--enable-libwebpmux \
--enable-libwebpdemux \
--enable-libwebpdecoder \
--disable-static
make
}
package() {
cd "$srcdir/$pkgname-$pkgver"
make DESTDIR="$pkgdir/" install
install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}
# vim:set ts=2 sw=2 et:
|
