blob: 53566fd25b8df06fbcaaaf689529b6c9f8e7f282 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
# $Id: PKGBUILD 120095 2011-04-19 21:39:40Z ibiru $
# Maintainer: damir <damir@archlinux.org>
pkgbase=libxml++
pkgname=('libxml++' 'libxml++-docs')
pkgver=2.34.1
pkgrel=1
arch=('i686' 'x86_64')
license=('LGPL')
url="http://libxmlplusplus.sourceforge.net/"
makedepends=('pkgconfig' 'glibmm-docs' 'libxml2' 'glibmm')
options=('!libtool' '!emptydirs')
source=(http://ftp.gnome.org/pub/GNOME/sources/${pkgbase}/2.34/${pkgbase}-${pkgver}.tar.bz2)
sha256sums=('664f3636c425554bf5e7d1b60253244e2d723899be8a971fc54332148bfce040')
build() {
cd "${srcdir}/${pkgbase}-${pkgver}"
./configure --prefix=/usr
make
}
package_libxml++() {
pkgdesc="C++ bindings to libxml2"
depends=('libxml2' 'glibmm')
replaces=('libxml++2')
provides=("libxml++2=${pkgver}")
conflicts=('libxml++2')
cd "${srcdir}/${pkgbase}-${pkgver}"
sed -i -e 's/install-data-am: install-data-local install-dist_referenceDATA/install-data-am: /' Makefile
make DESTDIR="${pkgdir}" install
}
package_libxml++-docs() {
pkgdesc="Developer documentation for libxml++"
depends=('glibmm-docs')
cd "${srcdir}/${pkgbase}-${pkgver}"
make DESTDIR="${pkgdir}" install-data-local install-dist_referenceDATA
}
|
