blob: 4c7532cfbd9efb5474fee13527599a5dd9c0817d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# $Id: PKGBUILD 145447 2011-12-22 13:02:48Z giovanni $
# Maintainer: Giovanni Scafora <giovanni@archlinux.org>
# Contributor: Gilles CHAUVIN <gcnweb@gmail.com>
pkgname=live-media
pkgver=2011.12.20
pkgrel=1
pkgdesc="A set of C++ libraries for multimedia streaming"
arch=('i686' 'x86_64')
license=('LGPL')
url="http://live555.com/liveMedia"
depends=('gcc-libs')
source=("http://live555.com/liveMedia/public/live.${pkgver}.tar.gz")
md5sums=('1bcbd2e45149c0d918c63df8f6d7d0e0')
build() {
cd ${srcdir}/live
sed \
-e 's/$(INCLUDES) -I. -O2 -DSOCKLEN_T/$(INCLUDES) -I. -O2 -I. -fPIC -DSOCKLEN_T/g' \
-e 's/\(LIBRARY_LINK =\).*/\1 $(LD) -o/g' \
-e 's/\(LIBRARY_LINK_OPTS =\).*/\1 $(LINK_OPTS) -r -Bstatic/g' \
-i config.linux
./genMakefiles linux
make
}
package() {
cd ${srcdir}/live
for dir in BasicUsageEnvironment UsageEnvironment groupsock liveMedia; do
mkdir -p ${pkgdir}/usr/lib/live/${dir}
cp -r ${dir}/*.a ${dir}/include ${pkgdir}/usr/lib/live/${dir}
done
mkdir -p ${pkgdir}/usr/bin
for testprog in `find testProgs -type f -perm 755`; do
install ${testprog} ${pkgdir}/usr/bin
done
}
|
