blob: cf09d5f97a0ba481b23e9bba27679fd7000ec054 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
|
# $Id: PKGBUILD 133449 2011-07-28 03:31:32Z heftig $
# Maintainer: Ronald van Haren <ronald.archlinux.org>
# Contributor: Jason Chu <jason@archlinux.org>
pkgname=lyx
pkgver=2.0.0
pkgrel=3
pkgdesc="An advanced open-source document processor."
arch=('i686' 'x86_64')
url="http://www.lyx.org"
depends=('qt' 'texlive-core' 'python2' 'perl' 'imagemagick' 'aspell' 'aiksaurus' 'boost-libs')
makedepends=('boost')
license=('GPL')
source=(ftp://ftp.lip6.fr/pub/lyx/stable/2.0.x/$pkgname-$pkgver.tar.xz \
lyx.desktop)
sha1sums=('27bf0ee623aae0e59780d9f627cdf5cb788a2516'
'e207a0b14d58aeb7b83f8fc47ab2e668cbc66844')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
find . -type f -exec sed -i 's|#!.*python|#!/usr/bin/env python2|' {} +
sed -i 's|"python|"python2|' lib/configure.py src/support/os.cpp
export CXXFLAGS="$CXXFLAGS -fpermissive"
./configure --prefix=/usr \
--with-frontend=qt4 --without-included-boost
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
# install desktop entry
install -Dm644 "${srcdir}/lyx.desktop" "${pkgdir}/usr/share/applications/lyx.desktop"
}
|
