blob: 217a30f3f7f6cb73f496d686b2139b2963728a2a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
# $Id: PKGBUILD 133025 2011-07-26 21:15:25Z eric $
# Maintainer: Giovanni Scafora <giovanni@archlinux.org>
pkgname=mkvtoolnix
pkgver=4.9.1
pkgrel=2
pkgdesc="Set of tools to create, edit and inspect Matroska files - CLI version"
arch=('i686' 'x86_64')
license=('GPL')
url="http://www.bunkus.org/videotools/mkvtoolnix/index.html"
depends=('file' 'boost-libs' 'libmatroska' 'lzo2' 'expat' 'flac' 'libvorbis')
makedepends=('boost' 'ruby')
source=("http://www.bunkus.org/videotools/${pkgname}/sources/${pkgname}-${pkgver}.tar.bz2")
md5sums=('5981f266e6d25da4a49f7464e4a97cdf')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
# Disable automagic curl dep used for online update checking
sed -i -e '/curl/d' configure.in
export CURL_CFLAGS="" CURL_LIBS=""
export CFLAGS="${CFLAGS} -DBOOST_FILESYSTEM_VERSION=2"
export CXXFLAGS="${CXXFLAGS} -DBOOST_FILESYSTEM_VERSION=2"
autoreconf
./configure --prefix=/usr \
--with-boost-libdir=/usr/lib \
--disable-gui
rake
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
rake DESTDIR="${pkgdir}" install
}
|
