blob: 67c31c1bd6a33f50a6dc1ed71a7af3f50226a10e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# $Id: PKGBUILD 196631 2013-10-15 21:31:37Z heftig $
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
pkgname=mutter-wayland
pkgver=3.10.1
pkgrel=1
pkgdesc="A Wayland compositor for GNOME"
arch=(i686 x86_64)
license=(GPL)
depends=(mutter)
makedepends=(intltool gnome-doc-utils)
url="http://www.gnome.org"
options=('!libtool' '!emptydirs')
install=mutter-wayland.install
source=(http://ftp.gnome.org/pub/gnome/sources/$pkgname/${pkgver:0:4}/$pkgname-$pkgver.tar.xz
mutter-wayland-3.10.0.1-logfile.patch)
sha256sums=('bdb6bcc25791309256b09ec9aa7e0be311ef311778450aafccb86caf2753b6b4'
'b79866b6b3fa6029b35ef2b5c5d0cb92886ec2ed0173f780c4d46a5b8d9a1644')
prepare() {
cd "$pkgname-$pkgver"
# From Fedora: Don't try to redirect the logfile. It won't work.
patch -Np1 -i ../mutter-wayland-3.10.0.1-logfile.patch
}
build() {
cd "$pkgname-$pkgver"
./configure --prefix=/usr --sysconfdir=/etc \
--libexecdir=/usr/lib/$pkgname \
--localstatedir=/var --disable-static \
--disable-schemas-compile --enable-compile-warnings=minimum
#https://bugzilla.gnome.org/show_bug.cgi?id=655517
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
make
}
package() {
cd "$pkgname-$pkgver"
make DESTDIR="$pkgdir" install
# Already in "mutter"
rm -r "$pkgdir"/usr/share/{man,gtk-doc,GConf,gnome-control-center}
rm "$pkgdir/usr/share/glib-2.0/schemas/org.gnome.mutter.gschema.xml"
}
|
