blob: d44412fc06a43cbbe67a36ab756740ce2bb6dd56 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# $Id: PKGBUILD 150735 2012-02-21 15:12:29Z stephane $
# Maintainer: Aaron Griffin <aaron@archlinux.org>
pkgbase=nasm
pkgname=('nasm' 'nasm-doc')
pkgver=2.09.10
pkgrel=2
arch=('i686' 'x86_64')
url="http://www.nasm.us"
license=('BSD')
makedepends=('ghostscript')
source=(http://www.nasm.us/pub/nasm/releasebuilds/${pkgver}/${pkgbase}-${pkgver}.tar.bz2)
md5sums=('15c79dcb5838870a0fac15feb5fade66')
sha1sums=('ca57a7454b29e18c64018e49cdf5c832937497ab')
build() {
cd "${srcdir}/${pkgbase}-${pkgver}"
./configure --prefix=/usr
make everything
}
package_nasm() {
pkgdesc="An 80x86 assembler designed for portability and modularity"
depends=('glibc')
install=nasm.install
cd "${srcdir}/${pkgbase}-${pkgver}"
make INSTALLROOT="${pkgdir}" install install_rdf
install -d "${pkgdir}/usr/share/info"
install -m644 doc/info/* "${pkgdir}/usr/share/info/"
install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/nasm/LICENSE"
}
package_nasm-doc() {
pkgdesc="An 80x86 assembler designed for portability and modularity (manuals)"
cd "${srcdir}/${pkgbase}-${pkgver}/doc"
install -d "${pkgdir}/usr/share/doc/nasm/html"
install -m644 html/* "${pkgdir}/usr/share/doc/nasm/html/"
install -m644 nasmdoc.ps nasmdoc.pdf nasmdoc.txt "${pkgdir}/usr/share/doc/nasm/"
install -D -m644 ../LICENSE "${pkgdir}/usr/share/licenses/nasm-doc/LICENSE"
}
|
