blob: e7dc2ef535a8c1e398e431adf3d91b4d1d2e2d61 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# $Id: PKGBUILD 196165 2013-10-07 12:54:42Z jgc $
# Maintainer: Jan de Groot <jgc@archlinux.org>
# Contributor: Alexander Baldeck <alexander@archlinux.org>
pkgname=nspr
pkgver=4.10.1
pkgrel=1
pkgdesc="Netscape Portable Runtime"
arch=(i686 x86_64)
url="http://www.mozilla.org/projects/nspr/"
license=('MPL' 'GPL')
depends=('glibc')
makedepends=('zip')
options=('!emptydirs')
source=(ftp://ftp.mozilla.org/pub/mozilla.org/nspr/releases/v${pkgver}/src/${pkgname}-${pkgver}.tar.gz)
sha1sums=('bd1cdf5e7e107846ffe431c5c62b81a560e8c3f7')
md5sums=('2e354084ca2bc5fbbb820762597f3890')
build() {
cd $pkgname-$pkgver
if [ "$CARCH" = "x86_64" ]; then
_confflags="--enable-64bit"
else
_confflags=""
fi
./nspr/configure \
--prefix=/usr \
--libdir=/usr/lib \
--includedir=/usr/include/nspr \
--enable-optimize \
--disable-debug ${_confflags}
make
}
package() {
cd $pkgname-$pkgver
make DESTDIR="$pkgdir" install
chmod 644 "$pkgdir"/usr/lib/*.a
ln -s nspr.pc "$pkgdir/usr/lib/pkgconfig/mozilla-nspr.pc"
rm -r "$pkgdir"/usr/bin/{compile-et.pl,prerr.properties} \
"$pkgdir/usr/include/nspr/md"
}
|
