blob: 753aa49a4e2b253f134a22dfbe852c9e3e49a611 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# $Id: PKGBUILD 149964 2012-02-11 23:31:17Z allan $
# Maintainer: Ronald van Haren <ronald.archlinux.org>
# Contributor : shining <shiningxc.at.gmail.com>
# Contributor : cyberdune <cyberdune@gmail.com>
pkgname=octave
pkgver=3.4.3
pkgrel=2
pkgdesc="A high-level language, primarily intended for numerical computations."
arch=('i686' 'x86_64')
url="http://www.octave.org"
license=('GPL')
depends=('fftw' 'pcre' 'curl' 'lapack' 'libx11' 'graphicsmagick' 'glpk' 'hdf5' 'gcc-libs' 'qhull')
makedepends=('texinfo' 'graphicsmagick' 'gcc-fortran' 'umfpack' 'texlive-core' 'fltk')
optdepends=('texinfo: for help-support in octave'
'gnuplot: alternative plotting'
'umfpack: LU decomposition of some large sparse matrices'
'fltk: alternative plotting')
source=("ftp://ftp.gnu.org/gnu/octave/octave-$pkgver.tar.bz2")
options=('!emptydirs')
install=octave.install
sha1sums=('fe622c28a38f8730c59e46211bc7b18e7f51a679')
build() {
cd ${srcdir}/${pkgname}-${pkgver}
# http://www.nabble.com/Random-rounding-errors-td16010966.html
FFLAGS="-O -ffloat-store" \
./configure --prefix=/usr --libexecdir=/usr/lib \
--enable-shared --disable-static --with-quantum-depth=16
LANG=C make
}
package(){
cd ${srcdir}/${pkgname}-${pkgver}
make DESTDIR="${pkgdir}" install
# add octave library path to ld.so.conf.d
install -d ${pkgdir}/etc/ld.so.conf.d
echo "/usr/lib/${pkgname}-${pkgver}" > ${pkgdir}/etc/ld.so.conf.d/${pkgname}.conf
}
|
