blob: 69ee66abb03e082fe86217b92254a2f9d5767425 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# $Id: PKGBUILD 211967 2014-05-02 08:41:20Z allan $
# Maintainer: Anatol Pomozov <anatol dot pomozov at gmail>
# Contributor: Stéphane Gaudreault <stephane@archlinux.org>
pkgname=openmpi
pkgver=1.8.1
pkgrel=2
pkgdesc='High performance message passing library (MPI)'
arch=(i686 x86_64)
url='http://www.open-mpi.org'
license=(custom)
depends=(libltdl hwloc)
makedepends=(inetutils valgrind gcc-fortran)
optdepends=('gcc-fortran: fortran support')
options=(staticlibs)
source=(http://www.open-mpi.org/software/ompi/v1.8/downloads/${pkgname}-${pkgver}.tar.bz2)
sha1sums=('e6e85da3e54784ee3d7b0bb0ff4d365ef2899c49')
build() {
cd $pkgname-$pkgver
# Make sure we use the system ltdl library rather than the ones in the tarball
rm -r opal/libltdl
./configure --prefix=/usr \
--sysconfdir=/etc/${pkgname} \
--enable-mpi-fortran=all \
--libdir=/usr/lib/${pkgname} \
--with-threads=posix \
--enable-smp-locks \
--with-valgrind \
--enable-memchecker \
--enable-debug \
--enable-pretty-print-stacktrace \
--without-slurm \
--with-hwloc=/usr \
--with-libltdl=/usr \
FC=/usr/bin/gfortran \
LDFLAGS="$LDFLAGS -Wl,-z,noexecstack"
make
}
package() {
cd $pkgname-$pkgver
make DESTDIR="$pkgdir" install
# FS#28583
install -d -m 755 "$pkgdir"/usr/lib/pkgconfig
for i in ompi-c.pc ompi-cxx.pc ompi-f77.pc ompi-f90.pc ompi.pc; do
ln -sf /usr/lib/openmpi/pkgconfig/$i "$pkgdir"/usr/lib/pkgconfig/
done
# Openmpi's otfinfo conflicts with the one from texlive
mv "$pkgdir"/usr/bin/otfinfo{,mpi}
# Remove dangling symlink and useless file
rm "$pkgdir"/usr/share/vampirtrace/config.log
install -d -m 755 "$pkgdir"/etc/ld.so.conf.d
echo "/usr/lib/$pkgname" > "$pkgdir"/etc/ld.so.conf.d/$pkgname.conf
install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}
|
