blob: 191577647bb1c38140b1318058b0de42fe7db77b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# $Id: PKGBUILD 163607 2012-07-16 23:59:16Z eric $
# Maintainer : Aaron Griffin <aaron@archlinux.org>
pkgname=oprofile
pkgver=0.9.7
pkgrel=4
pkgdesc="A system-wide profiler for Linux systems, capable of profiling all running code at low overhead"
arch=('i686' 'x86_64')
url="http://oprofile.sourceforge.net"
license=('GPL')
depends=('popt' 'gcc-libs' 'zlib' 'sh')
makedepends=('qt')
optdepends=('qt: for oprof_start gui')
options=('!libtool')
install=oprofile.install
source=(http://downloads.sourceforge.net/sourceforge/$pkgname/$pkgname-$pkgver.tar.gz)
sha1sums=('f5befd8aafc77d449e955f0585216f5d7b967de2')
build() {
cd "$srcdir/$pkgname-$pkgver"
./configure --prefix=/usr --with-kernel-support --with-x --enable-gui=qt4
make
}
check() {
cd "$srcdir/$pkgname-$pkgver"
make check
}
package() {
cd "$srcdir/$pkgname-$pkgver"
make DESTDIR="$pkgdir" install
install -d "$pkgdir/var/lib/oprofile"
# installing development libraries and headers - FS#20089
install -d "$pkgdir/usr/include/oprofile"
install -m644 config.h libop/op_*.h libregex/op_*.h libdb/odb.h \
libpp/{locate_images.h,image_errors.h} libutil/op_*.h \
libutil++/{op_*.h,bfd_support.h,utility.h,cached_value.h} "$pkgdir/usr/include/oprofile"
install -m644 libop/libop.a libdb/libodb.a "$pkgdir/usr/lib/"
install -m644 libabi/libabi.a "$pkgdir/usr/lib/libopabi.a"
install -m644 libutil/libutil.a "$pkgdir/usr/lib/liboputil.a"
install -m644 libutil++/libutil++.a "$pkgdir/usr/lib/liboputil++.a"
}
|
