blob: 2ef3a22e86a685c6e7a5579385cbcc4c4acc0d10 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# $Id: PKGBUILD 196150 2013-10-07 11:53:48Z jgc $
# Maintainer: Ionut Biru <ibiru@archlinux.org>
pkgbase=pygobject
pkgname=(python-gobject python2-gobject pygobject-devel)
pkgver=3.10.0
pkgrel=1
arch=(i686 x86_64)
url="https://live.gnome.org/PyGObject"
license=(LGPL)
makedepends=(python python2 python-cairo python2-cairo gobject-introspection)
source=(http://ftp.gnome.org/pub/gnome/sources/$pkgbase/${pkgver:0:4}/$pkgbase-$pkgver.tar.xz)
options=('!libtool')
sha256sums=('8aaa1f83fdb2e30bae77405a63a8be600b311a04a4cdc952b2ab62ee81aad077')
prepare() {
mkdir build-py2 build-py3 devel
cd ${pkgbase}-${pkgver}
sed -i '/Werror=format/d' configure # gcc 4.8
}
build() {
cd build-py2
../${pkgbase}-${pkgver}/configure --prefix=/usr --with-python=/usr/bin/python2
make
cd ../build-py3
../${pkgbase}-${pkgver}/configure --prefix=/usr
make
}
package_python-gobject() {
pkgdesc="Python 3 bindings for GObject"
depends=('gobject-introspection' 'python-cairo' "pygobject-devel=$pkgver")
cd build-py3
make DESTDIR="$pkgdir" install
rm -r "$pkgdir"/usr/{include,lib/pkgconfig}
}
package_python2-gobject() {
pkgdesc="Python 2 bindings for GObject"
depends=('gobject-introspection' 'python2-cairo' "pygobject-devel=$pkgver")
cd build-py2
make DESTDIR="$pkgdir" install
mv "$pkgdir"/usr/{include,lib/pkgconfig} "$srcdir/devel"
}
package_pygobject-devel() {
pkgdesc="Development files for the pygobject bindings"
cd "devel"
mkdir -p "$pkgdir"/usr/{include,lib}
mv include "$pkgdir/usr/"
mv pkgconfig "$pkgdir/usr/lib/"
}
|
