blob: 1b302e73178fc1f77f87af73d7be39cb972a22e7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# $Id: PKGBUILD 208037 2014-03-17 07:42:18Z fyan $
# Maintainer : Ionut Biru <ibiru@archlinux.org>
# Contributor: Alex Anthony <alex.anthony28991@gmail.com>
pkgname=('python-markupsafe' 'python2-markupsafe')
pkgver=0.19
pkgrel=1
pkgdesc="Implements a XML/HTML/XHTML Markup safe string for Python"
arch=('i686' 'x86_64')
url="http://pypi.python.org/pypi/MarkupSafe"
license=('custom')
makedepends=('python-setuptools' 'python2-setuptools')
source=("http://pypi.python.org/packages/source/M/MarkupSafe/MarkupSafe-${pkgver}.tar.gz")
md5sums=('ccb3f746c807c5500850987006854a6d')
build() {
cp -r MarkupSafe-${pkgver} python2-MarkupSafe-${pkgver}
cd "${srcdir}/MarkupSafe-${pkgver}"
python setup.py build
cd "${srcdir}/python2-MarkupSafe-${pkgver}"
python2 setup.py build
}
check() {
cd "${srcdir}/MarkupSafe-${pkgver}"
python setup.py test
cd "${srcdir}/python2-MarkupSafe-${pkgver}"
python2 setup.py test
}
package_python-markupsafe() {
depends=('python')
cd MarkupSafe-${pkgver}
python setup.py install --root="${pkgdir}" --optimize=1
install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/python-markupsafe/LICENSE"
}
package_python2-markupsafe() {
depends=('python2')
cd python2-MarkupSafe-${pkgver}
python2 setup.py install --root="${pkgdir}" --optimize=1
install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/python2-markupsafe/LICENSE"
}
|
