blob: b8d376acc49ac053a401983f5609d6936c3602da (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
|
# $Id: PKGBUILD 110651 2011-02-21 01:21:12Z stephane $
# Maintainer: Stéphane Gaudreault <stephane@archlinux.org>
# Maintainer: Allan McRae <allan@archlinux.org>
# Contributer: Jason Chu <jason@archlinux.org>
pkgname=python
pkgver=3.2
pkgrel=1
_pybasever=3.2
pkgdesc="Next generation of the python high-level scripting language"
arch=('i686' 'x86_64')
license=('custom')
url="http://www.python.org/"
depends=('expat' 'bzip2' 'gdbm' 'openssl' 'libffi' 'zlib')
makedepends=('tk' 'sqlite3' 'valgrind')
optdepends=('tk: for tkinter')
provides=('python3')
replaces=('python3')
options=('!makeflags')
source=(http://www.python.org/ftp/python/${_pybasever}/Python-${pkgver}.tar.xz)
sha1sums=('55a3a9d39f31563370d0c494373bb6d38e4d1a00')
build() {
cd "${srcdir}/Python-${pkgver}"
# Ensure that we are using the system copy of various libraries (expat, zlib and libffi),
# rather than copies shipped in the tarball
rm -r Modules/expat
rm -r Modules/zlib
rm -r Modules/_ctypes/{darwin,libffi}*
./configure --prefix=/usr \
--enable-shared \
--with-threads \
--with-computed-gotos \
--enable-ipv6 \
--with-valgrind \
--with-wide-unicode \
--with-system-expat \
--with-system-ffi
make
# Run the upstream test suite
# LD_LIBRARY_PATH="${srcdir}/Python-${pkgver}":${LD_LIBRARY_PATH} \
# "${srcdir}/Python-${pkgver}/python" -m test.regrtest -x test_distutils
}
package() {
cd "${srcdir}/Python-${pkgver}"
make DESTDIR="${pkgdir}" install maninstall
# Why are these not done by default...
ln -sf python3 "${pkgdir}/usr/bin/python"
ln -sf python3-config "${pkgdir}/usr/bin/python-config"
ln -sf idle3 "${pkgdir}/usr/bin/idle"
ln -sf pydoc3 "${pkgdir}/usr/bin/pydoc"
ln -sf python${_pybasever}.1 "${pkgdir}/usr/share/man/man1/python3.1"
# Fix FS#22552
ln -sf ../../libpython${_pybasever}mu.so \
"${pkgdir}/usr/lib/python${_pybasever}/config-${_pybasever}mu/libpython${_pybasever}mu.so"
# Clean-up reference to build directory
sed -i "s#$srcdir/Python-${pkgver}:##" "$pkgdir/usr/lib/python${_pybasever}/config-${_pybasever}mu/Makefile"
# License
install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|
