blob: d295893d57a258ddaf2ebfd884aa43b169a0e898 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
|
# $Id: PKGBUILD 186286 2013-05-23 20:40:14Z stephane $
# Maintainer: Stéphane Gaudreault <stephane@archlinux.org>
# Contributor: Allan McRae <allan@archlinux.org>
# Contributor: Jason Chu <jason@archlinux.org>
pkgname=python
pkgver=3.3.2
pkgrel=1
_pybasever=3.3
pkgdesc="Next generation of the python high-level scripting language"
arch=('i686' 'x86_64')
license=('custom')
url="http://www.python.org/"
depends=('expat' 'bzip2' 'gdbm' 'openssl' 'libffi' 'zlib')
makedepends=('tk>=8.6.0' 'sqlite' 'valgrind' 'bluez')
optdepends=('tk: for tkinter' 'sqlite')
provides=('python3')
replaces=('python3')
options=('!makeflags')
source=(http://www.python.org/ftp/python/${pkgver%rc*}/Python-${pkgver}.tar.xz
python-3.3.2-CVE-2013-2099.patch)
sha1sums=('87009d0c156c6e1354dfec5c98c328cae93950ad'
'b7a386b2e2f0811b344898500860ec31ba81ed4d')
build() {
cd "${srcdir}/Python-${pkgver}"
# FS#23997
sed -i -e "s|^#.* /usr/local/bin/python|#!/usr/bin/python|" Lib/cgi.py
# Ensure that we are using the system copy of various libraries (expat, zlib and libffi),
# rather than copies shipped in the tarball
rm -r Modules/expat
rm -r Modules/zlib
rm -r Modules/_ctypes/{darwin,libffi}*
patch -Np1 -i ../python-3.3.2-CVE-2013-2099.patch
./configure --prefix=/usr \
--enable-shared \
--with-threads \
--with-computed-gotos \
--enable-ipv6 \
--with-valgrind \
--with-system-expat \
--with-dbmliborder=gdbm:ndbm \
--with-system-ffi
make
}
check() {
cd "${srcdir}/Python-${pkgver}"
LD_LIBRARY_PATH="${srcdir}/Python-${pkgver}":${LD_LIBRARY_PATH} \
"${srcdir}/Python-${pkgver}/python" -m test.regrtest -x test_posixpath test_logging
}
package() {
cd "${srcdir}/Python-${pkgver}"
make DESTDIR="${pkgdir}" install maninstall
# Why are these not done by default...
ln -sf python3 "${pkgdir}/usr/bin/python"
ln -sf python3-config "${pkgdir}/usr/bin/python-config"
ln -sf idle3 "${pkgdir}/usr/bin/idle"
ln -sf pydoc3 "${pkgdir}/usr/bin/pydoc"
ln -sf python${_pybasever}.1 "${pkgdir}/usr/share/man/man1/python3.1"
# Fix FS#22552
ln -sf ../../libpython${_pybasever}m.so \
"${pkgdir}/usr/lib/python${_pybasever}/config-${_pybasever}m/libpython${_pybasever}m.so"
# Clean-up reference to build directory
sed -i "s|$srcdir/Python-${pkgver}:||" "$pkgdir/usr/lib/python${_pybasever}/config-${_pybasever}m/Makefile"
# License
install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|
