blob: 05191b22b785a0222916b0444ac93855f14bc5f3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
# $Id: PKGBUILD 130203 2011-07-04 08:57:57Z andrea $
# Maintainer: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Pierre Schmitz <pierre@archlinux.de>
pkgname=qtcurve-kde4
pkgver=1.8.8
pkgrel=1
arch=('i686' 'x86_64')
groups=('qtcurve')
license=('GPL')
pkgdesc='A configurable set of widget styles for KDE and Gtk'
url='http://www.kde-look.org/content/show.php?content=40492'
depends=('kdebase-workspace')
makedepends=('cmake' 'automoc4')
source=("http://craigd.wikispaces.com/file/view/QtCurve-KDE4-${pkgver}.tar.bz2"
'bypass-kde-config.patch')
md5sums=('b264d80b4c1e0e8d59e91d571cb639e4'
'3f6681147cc361bd2bfd4d7477f2a8d0')
build() {
cd "${srcdir}"/QtCurve-KDE4-${pkgver}
# Bypass KDE prefix detection by kde4-config, see:
# http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=541667
patch -p1 -i "${srcdir}"/bypass-kde-config.patch
cd "${srcdir}"
mkdir build
cd build
cmake ../QtCurve-KDE4-${pkgver} \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr
make
}
package() {
cd "${srcdir}"/build
make DESTDIR="${pkgdir}" install
}
|
