blob: 769dbc020f084400c426ee4af9794db9a2191559 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
|
# $Id: PKGBUILD 140990 2011-10-20 22:44:26Z eric $
# Maintainer: Eric Bélanger <eric@archlinux.org>
pkgname=quodlibet
pkgver=2.3.2
pkgrel=1
pkgdesc="An audio player written in pygtk"
arch=('i686' 'x86_64')
license=('GPL2')
url="http://code.google.com/p/quodlibet/"
depends=('gstreamer0.10-python' 'gstreamer0.10-base-plugins' 'gstreamer0.10-good-plugins'
'gstreamer0.10-ugly-plugins' 'mutagen' 'pygtk')
makedepends=('intltool')
optdepends=('gstreamer0.10-ffmpeg: for ffmpeg (ASF/WMA) support '
'gstreamer0.10-bad-plugins: for MPEG-4 (AAC) and Musepack support'
'dbus-python: for dbus support'
'notification-daemon: for notification support'
'libgpod: for ipod support'
'python-feedparser: for audio feeds (podcast) support'
'udisks: for media devices support'
'media-player-info: for media devices support')
options=('!makeflags')
source=(http://quodlibet.googlecode.com/files/${pkgname}-${pkgver}.tar.gz)
sha1sums=('21bc5fb988ca6c09959fc7212c05272a126a5be5')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
sed -i 's#env python#env python2#' *.py quodlibet/util/fmps.py
./setup.py build
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
./setup.py install --prefix="${pkgdir}/usr"
install -D -m644 quodlibet/images/exfalso.png "${pkgdir}/usr/share/pixmaps/exfalso.png"
install -D -m644 quodlibet/images/quodlibet.png "${pkgdir}/usr/share/pixmaps/quodlibet.png"
}
|
