blob: 12ed92004fd9258ab9ec312f5e0921eef0f0547e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
|
# $Id: PKGBUILD 153726 2012-03-18 19:57:52Z ronald $
# Maintainer: Ronald van Haren <ronald.archlinux.org>
# Contributor: Damir Perisa <damir.perisa@bluewin.ch>
# Contributor: K. Piche <kpiche@rogers.com>
pkgname=r
pkgver=2.14.2
pkgrel=1
pkgdesc="Language and environment for statistical computing and graphics"
arch=('i686' 'x86_64')
license=('GPL')
url=('http://www.r-project.org/')
depends=('blas' 'lapack' 'bzip2' 'libpng' 'libjpeg' 'libtiff'
'ncurses' 'pcre' 'readline' 'zlib' 'perl' 'gcc-libs'
'tk' 'libxt' 'libxmu' 'pango' 'xz')
makedepends=('openjdk6' 'gcc-fortran')
backup=('etc/R/Makeconf' 'etc/R/Renviron' 'etc/R/ldpaths' 'etc/R/repositories')
options=('!makeflags')
source=("http://cran.r-project.org/src/base/R-2/R-${pkgver}.tar.gz"
'r.desktop'
'r.png')
install=r.install
sha1sums=('523dca7694e4d0c8701fcc783ea3767e46fe7a62'
'13aa29219bcaa102e575de8c1c8e0833d233e836'
'a69a07ec363440efc18ce0a7f2af103375dea978')
build() {
cd "${srcdir}/R-${pkgver}"
sed -i 's|#define NeedFunctionPrototypes 0|#define NeedFunctionPrototypes 1|g' src/modules/X11/dataentry.c
./configure --prefix=/usr \
--libdir=/usr/lib \
--sysconfdir=/etc/R \
--datarootdir=/usr/share \
rsharedir=/usr/share/R/ \
rincludedir=/usr/include/R/ \
rdocdir=/usr/share/doc/R/ \
--with-x \
--enable-R-shlib \
--with-lapack \
--with-blas \
F77=gfortran \
LIBnn=lib
make
}
package() {
cd "${srcdir}/R-${pkgver}"
make -j1 DESTDIR="${pkgdir}" install
# Fixup R wrapper scripts.
sed -i "s|${pkgdir} ||" "${pkgdir}/usr/bin/R"
rm "${pkgdir}/usr/lib/R/bin/R"
cd "${pkgdir}/usr/lib/R/bin"
ln -s ../../../bin/R
# install some freedesktop.org compatibility
install -Dm644 "${srcdir}/r.desktop" \
"${pkgdir}/usr/share/applications/r.desktop"
install -Dm644 "${srcdir}/r.png" \
"${pkgdir}/usr/share/pixmaps/r.png"
# move the config directory to /etc and create symlinks
install -d "${pkgdir}/etc/R"
cd "${pkgdir}/usr/lib/R/etc"
for i in *; do
mv -f ${i} "${pkgdir}/etc/R"
ln -s /etc/R/${i} ${i}
done
}
|
