blob: 6c60cd7fe57e7f9b588565c3cf7ed3af4c8295fc (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
|
# $Id: PKGBUILD 216426 2014-07-03 19:05:41Z eric $
# Maintainer: Eric Bélanger <eric@archlinux.org>
# Contributor: Smith Dhumbumroong <zodmaner@gmail.com>
pkgname=re-alpine
pkgver=2.03
pkgrel=2
pkgdesc="The continuation of the Alpine email client from University of Washington"
arch=('i686' 'x86_64')
url="http://sourceforge.net/projects/re-alpine/"
license=('APACHE')
depends=('libldap' 'krb5' 'pam')
optdepends=('aspell: spell-checking support'
'hunspell: spell-checking support')
options=('!makeflags')
source=(http://downloads.sourceforge.net/project/re-alpine/${pkgname}-${pkgver}.tar.bz2
maildir.patch)
sha1sums=('8e1c4f4a4d38814478e8bd3bbeed1c0f8ee9491b'
'c09a8e42f9dba3e63a3755a9c418af95da721d8d')
prepare() {
cd ${pkgname}-${pkgver}
patch -p1 -i "${srcdir}/maildir.patch"
}
build() {
cd ${pkgname}-${pkgver}
LIBS+="-lpam -lkrb5 -lcrypto" ./configure --prefix=/usr --without-passfile --without-tcl \
--disable-shared --with-system-pinerc=/etc/alpine.d/pine.conf \
--with-system-fixed-pinerc=/etc/alpine.d/pine.conf.fixed
make
}
package() {
cd ${pkgname}-${pkgver}
make DESTDIR="${pkgdir}" install
}
|
