blob: 799ad8d431faa80768b1e861da9a726934993fd8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# $Id: PKGBUILD 127760 2011-06-18 07:02:05Z eric $
# Maintainer: tobias <tobias@archlinux.org>
# Contributor: Jochem Kossen <j.kossen@home.nl>
pkgname=rox
pkgver=2.10
pkgrel=2
pkgdesc="A small and fast file manager which can optionally manage the desktop background and panels"
arch=('i686' 'x86_64')
license=('GPL2')
url="http://roscidus.com/desktop/"
depends=('sh' 'libsm' 'libglade')
makedepends=('librsvg' 'python')
source=(http://downloads.sourceforge.net/sourceforge/${pkgname}/rox-filer-${pkgver}.tar.bz2 \
rox.desktop rox.svg rox.sh right-click.diff)
md5sums=('28e8494c9af783258ff86c830f8f0062'
'80e7a90e9d58375b25494fbdc01a05bd'
'658c8648b51e215558e13e6afb2b5c76'
'31578a90b241f0a8d09c9f8587608d00'
'2b2105a33070ac09a6352c29a5a17e4e')
build() {
cd "${srcdir}/rox-filer-${pkgver}/ROX-Filer"
patch -p2 -i "${srcdir}/right-click.diff"
./AppRun --compile
# finally we render a png as fallback for svg unaware menu applications
# Attention: always make sure you check the dimensions of the source-svg,
# you can read the dimensions via inkscape's export function
rsvg-convert -w 48 -h 38 -f png -o "${srcdir}/rox.png" "${srcdir}/rox.svg"
}
package() {
cd "${srcdir}/rox-filer-${pkgver}"
install -d "${pkgdir}/usr/share/Choices/MIME-types"
install -m755 Choices/MIME-types/* "${pkgdir}/usr/share/Choices/MIME-types/"
cp -rp ROX-Filer "${pkgdir}/usr/share/"
rm -fr "${pkgdir}"/usr/share/ROX-Filer/{src,build}
install -D -m755 "${srcdir}/rox.sh" "${pkgdir}/usr/bin/rox"
install -D -m644 rox.1 "${pkgdir}/usr/share/man/man1/rox.1"
ln -sf rox.1 "${pkgdir}/usr/share/man/man1/ROX-Filer.1"
install -D -m644 "${srcdir}/rox.desktop" "${pkgdir}/usr/share/applications/rox.desktop"
install -D -m644 "${srcdir}/rox.svg" "${pkgdir}/usr/share/pixmaps/rox.svg"
install -D -m644 "${srcdir}/rox.png" "${pkgdir}/usr/share/pixmaps/rox.png"
}
|
